Chrome extension to convert text to 'Sentence case.'

Question

I am looking for a Chrome extension that can, with a keyboard shortcut, convert text to Sentence case and vice versa.

For example:

.THIS IS A SAMPLE TEXT

should be converted to

.This is a sample text

Requirements:

• Keeps letter after . as a capital (for a sentence)
• Keyboard shortcut
• Works in website textboxes/textareas etc.
• Works on Chrome in Windows 7 and OSX 10.6.8

NOTE: I am not looking for this to convert the text in the clipboard. I am looking for a solution that works with the selected text inside a textbox/textarea in a website.

Answer 1

A script to do it with AutoHotkey (scripting language for desktop automation on Windows), in case it's ok not to be browser only:

CTL+ALT+k - Sentence case (what you asked for)
CTL+L - convert to lowercase
CTL+U - convert to uppercase
CTL+K - invert the case (e.g. "The Big Dog" becomes "tHE bIG dOG")
SHIFT+CTL+K - convert to capitalized (e.g. "the big dog" becomes "The Big Dog")
SHIFT+CTL+U - convert to sentence case

Code:

!^k::                                           ; Sentence case
StringLower, Clipboard, Clipboard
Clipboard := RegExReplace(Clipboard, "((?:^|[.!?]\s+)[a-z])", "$u1")
Send %Clipboard%
RETURN

^u::                                                                 ; Convert text to upper
 StringUpper Clipboard, Clipboard
 Send %Clipboard%
RETURN

^l::                                                                 ; Convert text to lower
 StringLower Clipboard, Clipboard
 Send %Clipboard%
RETURN

+^k::                                                                ; Convert text to capitalized
 StringUpper Clipboard, Clipboard, T
 Send %Clipboard%
RETURN

^k::                                                                 ; Convert text to inverted
 Lab_Invert_Char_Out:= ""
 Loop % Strlen(Clipboard) {
    Lab_Invert_Char:= Substr(Clipboard, A_Index, 1)
    if Lab_Invert_Char is upper
       Lab_Invert_Char_Out:= Lab_Invert_Char_Out Chr(Asc(Lab_Invert_Char) + 32)
    else if Lab_Invert_Char is lower
       Lab_Invert_Char_Out:= Lab_Invert_Char_Out Chr(Asc(Lab_Invert_Char) - 32)
    else
       Lab_Invert_Char_Out:= Lab_Invert_Char_Out Lab_Invert_Char
 }
 Send %Lab_Invert_Char_Out%
RETURN

Example:

• dvfv dKMLM sdf. sdf SDFKLMSF sdf. -> Dvfv dkmlm sdf. Sdf sdfklmsf sdf.

Answer 2

Building on Franck's AutoHotKey answer, mostly from here, is this script:

#d:: ConvertSentence()

ConvertSentence()
{
    clipSave := Clipboard
    Clipboard = ; Empty the clipboard so that ClipWait has something to detect
    SendInput, ^c ;copies selected text
    ClipWait
    StringReplace, Clipboard, Clipboard, `r`n, `n, All ;Fix for SendInput sending Windows linebreaks 
    StringLower, Clipboard, Clipboard ;Convert case
    Clipboard := RegExReplace(Clipboard, "(((^|([.!?]+\s+))[a-z])| i | i')", "$u1")
    Len:= Strlen(Clipboard) ;Set number of characters
    Send %Clipboard% ;Send new string
    Send +{left %Len%} ;Re-select text
    VarSetCapacity(OutputText, 0) ;free memory
    Clipboard := clipSave ;Restore previous clipboard
}

When you press Windows + D, the selected text will be converted to Sentence case.

Unfortunately AutoHotKey is only for Windows, so this won't work on Chrome on all platforms!