Tool to keep branched and refactored C++ code in sync?

Question

I'm searching for a Windows GUI/command line tool or Visual Studio plug-in where I can automate the extraction of C++ code blocks, add some refactoring/renaming steps and insert it into some other C++ file. Once this is setup I want to keep the code blocks source/destination in sync and/or check for diffs.

EDIT: I'm trying to keep things in my project as simple as possible. So I'm hoping for a solution with a low level of complexity. I would prefer a solution utilizing several single task tools (maybe already shipped with my OS/IDE/SCM) over a feature-rich multi-task tool which is build to handle much more.

An Example

To give a very simple example - and I'm not sure if the tool in question would even need to understand the C++ syntax for doing something like this:

OldClass.cpp

class OldClass
{
public:
   ...
   void MyFunctionToReuse()
   {
       ...
       // Start OldClass::MyFunctionToReuse() block
       mVarOldName = ...;
       // End OldClass::MyFunctionToReuse() block
       ...
   }
};

NewClass.cpp

class NewClass
{
public:
   ...
   void SomeFunction()
   {
       ...
       // Start OldClass::MyFunctionToReuse() block
       // file OldClass.cpp, line 100 - 110
       // renamed mVarOldName to mVarNewName
       mVarNewName = ...;
       // End OldClass::MyFunctionToReuse() block
       ...
   }
};

The possibilities I'm currently seeing

I see four possible ways of doing this:

1. Manually extract the code I want to reuse into C++ templates/classes/functions
2. Use C++ refactoring tools with a macro recording feature
3. Use a transpiler with a set of rules to convert OldClass to NewClass
4. A text tool only based approach searching for keywords in comments (copy/rename/diff/insert)

The Rationale

I have a long lasting model/view/controller C++ project where the view part is now to be exchanged/moved into a separate application. The old code base is to 80% reusable, but I can't take the classes as they currently are. So I'm now at a point where I branch from my old project to start on the new code.

But the old project will still be to maintained for several years. So if I start with the necessary changes for / refactoring of the new project, I'm searching for something to keep both code streams/branches in sync (mainly for bugfixes).

And huge changes to the old product are only the last resort, because it would mean - even with having a good code coverage with unit tests - retesting major parts of the currently shipping product.

What I've looked into so far

The feature lists of

• The refactoring tools listed here
  • But I didn't find a scripting/macro recording feature in those (ReSharper, Visual Assist, ...)
  • They seem to handle mostly transformations of single code base in one direction
• The transpilers listed here or here
  • But the ROSE compiler infrastructure and DMS Software Reengineering Toolkit with C++ Parser Frontend seem oversized
  • I think I would rather go the C++ way to split and retest my old project's functionality, before putting to much time into learning to use the transpilers
• The Pattern-matching and -rewriting source code software listed here

Answer 1

I ended up using Visual Studio's pre-compiler to translate my source files via macro definitions. In a second step I'm using PowerShell to replace/add some special formatting characters that the pre-compiler would remove/ignore.

Since I'm using CMake, here is the script I've tested:

cmake_minimum_required(VERSION 2.8.9)

project(CppTranslationDemo)

if(NOT MSVC_VERSION GREATER 1699)
    message(FATAL_ERROR "Only tested with VS2012 or above")
endif()

set(
    inFiles
    OldClass.cpp
)
unset(outFiles)

find_program(
    POWERSHELL_EXE
        NAMES powershell.exe
        PATHS C:/Windows/System32
        PATH_SUFFIXES WindowsPowerShell/v1.0
)
if (NOT POWERSHELL_EXE)
    message(FATAL_ERROR "Couldn't find powershell.exe")
endif()

foreach(_file IN ITEMS ${inFiles})
    file(TO_NATIVE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/${_file}" _file_native_path)
    file(TO_NATIVE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/TranslationMacros.h" _macro_file_native_path)
    file(TO_NATIVE_PATH "${CMAKE_CXX_COMPILER}" _compiler_native_path)

    get_filename_component(_file_name "${_file}" NAME)
    get_filename_component(_file_ext "${_file}" EXT)

    string(REPLACE "Old" "New" _file_name "${_file_name}")
    set(_out_file "${CMAKE_BINARY_DIR}/${_file_name}")

    set(
        _powershell_cmd_list
        "$i = 1;"
        # NOTE: increase column width to prevent word wrap after 80 chararcters
        "$Host.UI.RawUI.BufferSize = New-Object Management.Automation.Host.Size (500, 25);"
        "$nl = [Environment]::NewLine;"
        "& '${_compiler_native_path}' /nologo /EP /C /FI${_macro_file_native_path} ${_file_native_path}"
        "|"
        "Foreach-Object"
        "{"
            "$_"
            "-replace '@NL@', $nl"
            "-replace '@TAB@', '    '"
            "-replace '@H@', '#'"
            "-replace '@C@', '//'"
            "-replace '@CB@', '/*'"
            "-replace '@CE@', '*/'"
            "-replace '@.*@', ''"
        "}"
        "|"
        "where"
        "{"
            "if ($_ -eq '')"
            "{" 
                "$i++;" 
            "}" 
            "else"
            "{" 
                "$i = 0;" 
            "}"
            "($i -lt 2)"
        "};"
        "exit $LASTEXITCODE"
    )
    string(REGEX REPLACE ";([^;])" " \\1" _powershell_cmd "${_powershell_cmd_list}")

    add_custom_command(
        OUTPUT          ${_out_file} 
        COMMAND         "${POWERSHELL_EXE}" -Command "${_powershell_cmd}" 1> "${_out_file}"
        DEPENDS         ${_file}
                        TranslationMacros.h
        COMMENT         "${_out_file}"
    )

    list(APPEND outFiles "${_out_file}")
endforeach() 

add_custom_target(
    ${PROJECT_NAME}
        DEPENDS ${outFiles}
        SOURCES 
            TranslationMacros.h
            ${inFiles}
)
set_source_files_properties(${outFiles} PROPERTIES GENERATED 1)

add_library(
    ${PROJECT_NAME}Test
    ${outFiles} 
)
add_dependencies(
    ${PROJECT_NAME}Test
    ${PROJECT_NAME}
)

Combined with

TranslationMacros.h

#define OldClass            NewClass
#define MyFunctionToReuse   SomeFunction
#define mVarOldName         mVarNewName 

Does translate

OldClass.cpp

class OldClass
{
public:
   OldClass() : mVarOldName(0) {}

   void MyFunctionToReuse()
   {
       // Some test comment
       mVarOldName = 1;
   }

   int mVarOldName;
};

Into

NewClass.cpp

class NewClass
{
public:
   NewClass() : mVarNewName(0) {}

   void SomeFunction()
   {
       // Some test comment
       mVarNewName = 1;
   }

   int mVarNewName;
};

References

Visual Studio

• /EP (Preprocess to stdout Without #line Directives)
• /C (Preserve Comments During Preprocessing)
• /FI (Name Forced Include File)

PowerShell

• Powershell output column width
• Powershell -command's exit code is not the same as a script's exit code
• How do I add a newline to command output in PowerShell?
• Executing an EXE file using a PowerShell script